Bitlocker磁盘锁加密开启/关闭管理工具V1.0

Love0912 · 发表于 2026-4-15 12:52

本帖最后由 Love0912 于 2026-4-16 15:27 编辑

这是个简单的小工具，但是说实话我并不确定他就是应该发布在精品软件区还是这个编程语言区，因为按我的理解他应该属于软件，因为我的最初期望是把它当软件看的，但是奈何咱就会写点批处理。。其他不会~~ 最终选择只能发布在这里了，有管理路过的时候麻烦给指点一下这玩意能发软件区么。。

这工具本身没啥亮点，只是之前用的联想开发的那个工具，现在要求又得扫码又得登录啥的特别麻烦，而且不太好用，故而才自己动手写了这么个玩意儿！
PS：这东西只是一个装机工具而已，他并不能在你没有秘钥的前提下解密，请勿过度解读、夸大这个工具的作用。。。

--------------------26.04.16更新V1.1版本----------
对原来的版本做了优化，将原来的解密选项修改成了拷贝密钥选项，防止密码丢失。
对输入方式做了限制，避免一些小可爱输入错误的盘符或者字符导致磁盘打开异常。
更新帮助文件内容，你可以通过手动操作这些命令实现所有功能。
最后，已知有一个BUG，在开启磁盘加密里面，如果你本身有加密再次加密时它会提示一些奇怪的信息，但是经过测试并不影响使用。实在懒得折腾了就这样吧

最后忍不住吐槽一句：兄弟们当年发现一个BUG但是不影响使用的时候千万别手贱去修复，挺简单的一个脚本，就是因为手贱折腾了我好几个小时，我都崩溃了

----------------
好了回归正题，这是一个微软磁盘锁的管理工具，用的都是官方原生态的命令，具体不做过多介绍，自己看图就行了！
主页面

磁盘状态查询

磁盘加密

磁盘解密

大概就是这么个东西了，感兴趣的可以自己看源码

[Asm] 纯文本查看 复制代码

@echo off
cls
:qy
color 0F
cls
echo                                    Bitlocker磁盘加密管理工具 V1.0
echo     ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╗
echo.    ┋                  请使用管理员身份运行此脚本，避免权限不足影响效果！！
echo.    ┋
echo     ┋                  本软件可以一键开启/关闭系统Bitlocker磁盘加密
echo     ┋
echo.    ┋        〖1.开启磁盘加密〗                 〖2.关闭磁盘加密〗
echo.    ┋        〖3.查询进度/状态〗                〖4.磁盘解密〗         〖5.Help帮助文件〗
echo.    ┋                                       ╔┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┋
echo     ┋                                              〖作者：二虎电脑〗 ┋   Z.退出程序┋
echo.    ╚┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉┉╝
:input
echo 请您根据需要选择对应的操作！！
echo.
set choice=
set /p choice=          请输入对应的按回车:
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
if /i "%choice%"=="1" goto kqjm
if /i "%choice%"=="2" goto gbjm
if /i "%choice%"=="3" goto ztcx
if /i "%choice%"=="4" goto cpjm
if /i "%choice%"=="5" goto help
if /i "%choice%"=="Z" goto end
goto qy

:help
cls
color 4f
echo 磁盘解密命令：
echo.
echo manage-bde -off f: (F替换为实际盘符即可，注意空格）
echo.
echo.
echo.
echo 进度查询命令：
echo.
echo manage-bde -status
echo.
echo 当加密百分百为"0.0%"，说明BitLocker加密已经关闭。
echo.
echo.
echo.
echo.
echo 磁盘加密关闭命令：（使用WIN+X选择Windows PowerShell选项）
echo.
echo Disable-BitLocker -mount "F:"(F替换为实际盘符即可，注意空格）【这个和上面的解密命令效果差不多，只是手段不同而已】
echo.
echo 运行后观测最右侧Protection Status选项下为OFF标识则代表关闭成功。
echo.
echo.
echo.
echo 以上就是所有命令的手动操作模式。摁任意键关闭本窗口并返回主页面！
pause
goto qy

:cpjm
cls
echo 【磁盘解密 —— 关闭加密】
echo 请输入要解密的盘符，如：c【仅输入盘符即可】
set cpjm=
set /p cpjm=请输入盘符:
IF NOT "%cpjm%"=="" SET cpjm=%cpjm:~0,1%
manage-bde -off "%cpjm%:"
echo.
echo 操作完成，按任意键查看状态
pause >nul
manage-bde -status "%cpjm%:"
pause
goto qy

:kqjm
cls
echo 【开启磁盘加密】
echo 请输入要加密的盘符，如：c【仅输入盘符即可】
set kqjm=
set /p kqjm=请输入盘符:
IF NOT "%kqjm%"=="" SET kqjm=%kqjm:~0,1%
cls
echo ╔═════════════════════════════════════════════════╗
echo        【重要提示：输入密码时 **不显示任何字符**】
echo          这是系统安全机制，不是没输入进去！！
echo        输入完成直接按回车，会要求再输入一次确认
echo ╚═════════════════════════════════════════════════╗
echo.
manage-bde -on "%kqjm%:" -pw
echo.
echo 加密已启动，按任意键查看状态
pause >nul
manage-bde -status "%kqjm%:"
pause
goto qy

:gbjm
cls
echo 【关闭磁盘加密】
echo 请输入要关闭加密的盘符，如：c【仅输入盘符即可】
set gbjm=
set /p gbjm=请输入盘符:
IF NOT "%gbjm%"=="" SET gbjm=%gbjm:~0,1%
powershell "Disable-BitLocker -MountPoint '%gbjm%:'"
echo.
echo 关闭加密已执行，按任意键查看状态
pause >nul
manage-bde -status "%gbjm%:"
pause
goto qy

:ztcx
cls
echo 【查询加密状态/进度】
echo 请输入要查询的盘符，如：c【仅输入盘符即可】
set ztcx=
set /p ztcx=请输入盘符:
IF NOT "%ztcx%"=="" SET ztcx=%ztcx:~0,1%
manage-bde -status "%ztcx%:"
pause
goto qy

:end
exit

其他没啥可说的，喜欢的可以拿去随便用，没有版权一说，唯一诉求，拿去随便改的时候能把作者署名给咱留下，好歹写这么多代码也怪辛苦的，多少提咱一嘴

好了，下载地址【蓝凑】
https://wwbbq.lanzoue.com/imEds3nart4h

tdasly · 发表于 2026-4-15 14:34

win10家庭版支持吗

kaguyaai · 发表于 2026-4-16 15:55

挺好用的小工具，使用中发现需要手动管理员和手动输入盘符不是很方便。
对其增加了管理员提权和全部磁盘一键解密和全部磁盘查询状态。
有需要的可以自行复制到bat，编码ansi。

[Asm] 纯文本查看 复制代码

@echo off

title BitLocker 检测解密工具
:: 自动管理员
fltmc >nul 2>&1 || (
    echo 请求管理员权限...
    powershell "Start-Process cmd -ArgumentList '/c ""%~f0""' -Verb RunAs" >nul
    exit /b
)

cls
:qy
color 0F
cls
echo ==============================================================================
echo          BitLocker 磁盘加密检测工具 V1.1
echo ==============================================================================
echo.
echo             本软件可以一键开启/关闭系统Bitlocker磁盘加密
echo.    
echo.             ● 1.查询状态，加/解密进度
echo.             ● 2.关闭磁盘加密 
echo.             ● 3.开启磁盘加密
echo.             ● 4.磁盘解密 
echo.      
:input
echo.
set choice=
set /p choice=          请输入对应的按回车(默认查询):
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
if /i "%choice%"=="1" goto cx
if /i "%choice%"=="2" goto gb
if /i "%choice%"=="3" goto kq
if /i "%choice%"=="4" goto jm
goto cx
 
:jm
cls
echo 【磁盘解密 —— 关闭加密】
echo 请输入要解密的盘符，如：c【仅输入盘符即可】
set cpjm=
set /p cpjm=请输入盘符:
IF NOT "%cpjm%"=="" SET cpjm=%cpjm:~0,1%
manage-bde -off "%cpjm%:"
echo.
echo 操作完成，按任意键查看状态
pause >nul
manage-bde -status "%cpjm%:"
pause
goto qy
 
:kq
cls
echo 【开启磁盘加密】
echo 请输入要加密的盘符，如：c【仅输入盘符即可】
set kqjm=
set /p kqjm=请输入盘符:
IF NOT "%kqjm%"=="" SET kqjm=%kqjm:~0,1%
cls
echo ╔═════════════════════════════════════════════════╗
echo        【重要提示：输入密码时 **不显示任何字符**】
echo          这是系统安全机制，不是没输入进去！！
echo        输入完成直接按回车，会要求再输入一次确认
echo ╚═════════════════════════════════════════════════╗
echo.
manage-bde -on "%kqjm%:" -pw
echo.
echo 加密已启动，按任意键查看状态
pause >nul
manage-bde -status "%kqjm%:"
pause
goto qy
 
:gb
cls
echo 【关闭磁盘加密】
echo.
echo ==============================================================================
echo.
echo 即将一键解密所有磁盘！
echo.
set /p "ok=确认开始解密所有磁盘吗？(Y/N)："
if /i not "%ok%"=="Y" (
    echo 已取消解密,按任意键返回主菜单
    pause >nul
	goto main
    exit
)

echo.
echo ========================= 正在解密所有磁盘 =========================
echo.

:: 一键解密所有存在的磁盘（你要的命令）
for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    dir %%d:\ >nul 2>&1
    if not errorlevel 1 (
        echo 正在解密：%%d:
        powershell "Disable-BitLocker -MountPoint '%%d:'"
        echo.
    )
)

echo.
echo ========================= 解密指令已全部下发 =========================
echo 解密需要时间，回车查询进度。
pause >nul
goto cx
 

:cx
cls
setlocal enabledelayedexpansion
cls
echo.
echo 【检测结果】
echo ==============================================================================
echo 盘符      大小            转换状态          锁定状态          已加密百分比:
echo ==============================================================================

for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    dir %%d:\ >nul 2>&1
    if not errorlevel 1 (
        set "size="
        set "conv="
        set "lock="
		set "jindu="
        
        for /f "tokens=1* delims=:" %%a in ('manage-bde -status %%d: 2^>nul') do (
            set "key=%%a"
            set "val=%%b"
            set "key=!key: =!"
            set "val=!val:~1!"

            if "!key!"=="大小" (
                set "size=!val!"
            )
            if "!key!"=="转换状态" (
                set "conv=!val!"
            )
            if "!key!"=="锁定状态" (
                set "lock=!val!"
            )
			if "!key!"=="已加密百分比" (
                set "jindu=!val!"
            )
        )

        echo %%d:  !size! !conv!  !lock! !jindu!
    )
)

echo.
echo ==============================================================================
echo 按任意键返回主菜单
pause >nul
goto qy

skyshiyi · 发表于 2026-4-15 13:14

感谢分享！！！

520pojie0 · 发表于 2026-4-15 13:58

挺好的小工具

ftpc · 发表于 2026-4-15 14:07

支持原创，感谢分享

门外雪、屋中炉 · 发表于 2026-4-15 14:29

感谢楼主热心分享

不知无错 · 发表于 2026-4-15 14:30

感谢分享，就是我在使用最全驱动PE这个pe系统U盘装机时，不知道为啥就会爆出Bitlocker磁盘锁已加密，导致我不能选择要重装的系统镜像。

hezhiyong · 发表于 2026-4-15 14:38

感谢分享！

昨天√ · 发表于 2026-4-15 14:52

建议所有人关闭这玩意，关闭这玩意

magiclyan · 发表于 2026-4-15 15:27

本帖最后由 magiclyan 于 2026-4-15 15:29 编辑

结论：允许发布在软件区但是不允许发布在原创区
注意发布在软件区的尽量不要带有大篇幅代码
理由：
1、是软件，即便是简单打包的软件；只要是软件都可以发布在软件区
2、对于简单封装调用别人接口的、AI参与编写的程序不算原创，禁止发布原创区；修改版权、拿别人源代码进行篡改冒充原创作品的行为我们将严惩不贷！

帐号		自动登录	找回密码
密码			注册[Register]

[其他原创] Bitlocker磁盘锁加密开启/关闭管理工具V1.0

免费评分