求一款可以批量除头去尾音频的软件

shelti

求助一款可以批量除头去尾 音频的软件

Batcher

[Asm] 纯文本查看 复制代码

@echo off
chcp 65001 >nul
cd /d "%~dp0"
REM 处理之后的文件保存在哪个文件夹
set "NewFolder=Out"
md "%NewFolder%" 2>nul
for /f "delims=" %%a in ('dir /b /a-d *.mp3') do (
    echo --- 正在处理：%%a
    set "FileName=%%a"
    setlocal enabledelayedexpansion
    for /f "delims=." %%i in ('ffprobe.exe -v error -show_entries format^=duration -of default^=noprint_wrappers^=1:nokey^=1 "!FileName!"') do (
        REM 删除结尾10秒
        set /a KeepSec=%%i-10
    )
    echo !KeepSec!
    REM 删除开头5秒
    ffmpeg.exe -v error -ss 0:00:05 -i "!FileName!" -t !KeepSec! -c copy "%NewFolder%\!FileName!"
    endlocal
)
pause

打开记事本，复制粘贴以上代码，文件，另存为：
    文件名：MyRun.bat
    编码：UTF-8
下载命令行工具 FFmpeg 例如：ffmpeg-n7.0-latest-win64-gpl-7.0.zip
    https://github.com/BtbN/FFmpeg-Builds/releases
解压缩之后把 ffmpeg.exe 和 ffprobe.exe 和 MyRun.bat 和待处理的音频文件放在同一个文件夹下
双击执行脚本：MyRun.bat
测试代码之前，请务必备份好原始数据。

sun0516

格式工厂
https://www.123pan.com/s/A6cA-drkJh

misael2018

我自己一直用的这个

CR Video mate综合处理工具

链接：https://pan.quark.cn/s/f85abcb110e6

zpolar

goldwave最强大，论坛有

shelti

Batcher 发表于 2024-6-14 12:29
[mw_shl_code=asm,true]@echo off
chcp 65001 >nul
cd /d "%~dp0"

这个太赞了，小白也学会了！！