求一款神器——按日期和时间一键生成新建文件夹

haiyuanbo

哪位大神，麻烦弄个按日期和时间一键生成新建文件夹名称的神器，最好是年、月、日、时、分都有，即时创建就即时生成当年当日的时间，最好是按右键菜单创建就方便多了，全网都没找到这种软件，这应该是原创了吧

roothalo

[Bash shell] 纯文本查看 复制代码

:: 关闭终端回显
@echo off
:: 以下所有 echo 开头的行均可删除，在此脚本中 echo 仅为显示用
set CURRENT_YEAR_STRING=%date:~0,4%
set CURRENT_MONTH_STRING=%date:~5,2%
set CURRENT_DAY_STRING=%date:~8,2%
set "TIME_STRING_FILL_ZREO=%time: =0%"
set CURRENT_HOUR_STRING=%TIME_STRING_FILL_ZREO:~0,2%
set CURRENT_MINUTE_STRING=%TIME_STRING_FILL_ZREO:~3,2%
set CURRENT_SECOND_STRING=%TIME_STRING_FILL_ZREO:~6,2%
set CURRENT_DATE_TIME_STRING=%CURRENT_YEAR_STRING%.%CURRENT_MONTH_STRING%.%CURRENT_DAY_STRING%.%CURRENT_HOUR_STRING%.%CURRENT_MINUTE_STRING%

:: 创建文件夹
md %CURRENT_DATE_TIME_STRING%

新建文本文档 修改后缀名为 名称.bat
内容填充上面的内容。
双击该文件即可新建时间文件夹。

haiyuanbo

不知道在哪里上传图片，创建的文件夹名称显示是这样，比如：2024.3.27.23.45

syd1990

https://f.ws59.cn/f/dqeywdh7pn5 复制链接到浏览器打开   
下载直接用，加了秒， 需要在哪里创建就放哪里点开就行了。

Batcher

[Asm] 纯文本查看 复制代码

@echo off
for /f "tokens=2 delims==" %%i in ('wmic Path Win32_OperatingSystem get LocalDateTime /value ^| findstr "="') do (
    set "now=%%i"
)
set "NewFolder=%now:~0,4%.%now:~4,2%.%now:~6,2%.%now:~8,2%.%now:~10,2%.%now:~12,2%"
md "%NewFolder%"

打开记事本，复制粘贴以上代码，文件，另存为：
文件名: MyRunV1.bat
编码: ANSI
双击执行脚本: MyRunV1.bat
测试代码之前，请务必备份好原始数据。

Batcher

[Asm] 纯文本查看 复制代码

@echo off
for /f "delims=" %%i in ('powershell -c "Get-Date -UFormat '%%Y%%m%%d%%H%%M%%S'"') do (
    set "now=%%i"
)
set "NewFolder=%now:~0,4%.%now:~4,2%.%now:~6,2%.%now:~8,2%.%now:~10,2%.%now:~12,2%"
md "%NewFolder%"

打开记事本，复制粘贴以上代码，文件，另存为：
文件名: MyRunV2.bat
编码: ANSI
双击执行脚本: MyRunV2.bat
测试代码之前，请务必备份好原始数据。

使用图床发截图
https://www.52pojie.cn/thread-1455093-1-1.html

haiyuanbo

roothalo 发表于 2024-3-28 00:41
[mw_shl_code=bash,true]:: 关闭终端回显
@echo off
:: 以下所有 echo 开头的行均可删除，在此脚本中 ech ...

大神，你这个可以创建，请问怎么放到鼠标右键菜单里呢？

roothalo

haiyuanbo 发表于 2024-3-28 19:15
大神，你这个可以创建，请问怎么放到鼠标右键菜单里呢？

那个就比较麻烦了，我也没弄过

zhonghzong

@echo off
REM 获取当前日期和时间
for /f "tokens=1-6 delims=/:. " %%a in ("%date% %time%") do (
    set "year=%%d"
    set "month=%%b"
    set "day=%%c"
    set "hour=%%e"
    set "minute=%%f"
)

REM 创建文件夹
set "folder_name=%year%-%month%-%day%_%hour%-%minute%"
mkdir "%folder_name%"
echo 文件夹 %folder_name% 已创建。
pause

txt保存然后改成bat可执行文件