本帖最后由 Batcher 于 2023-12-31 12:15 编辑
【功能描述】
- 批量给视频添加片头。
- 批量给视频添加片尾。
- 批量给视频添加片头和片尾。
【下载地址】
百度网盘: https://pan.baidu.com/s/1nd4d5ECnAVLhAuQ2PNaZjQ 密码:52PJ
蓝奏网盘: https://batcher.lanzouj.com/i0rx21jgboob 密码:52PJ
【使用方法】
- 下载之后解压缩，得到的 AddPrefixSuffix.bat 和待处理的视频文件放在同一个文件夹下。
- 片头视频放在 Resource 文件夹下命名为 PianTou.mp4
- 片尾视频放在 Resource 文件夹下命名为 PianWei.mp4
- 下载命令行工具 FFmpeg 例如：ffmpeg-n6.0-latest-win64-gpl-6.0.zip https://github.com/BtbN/FFmpeg-Builds/releases
- 解压缩之后把 ffmpeg.exe 和此脚本放在同一个文件夹下
- 双击执行 AddPrefixSuffix.bat 脚本。
如果除了mp4之外还需要处理其它格式的视频，请自行修改代码里面的.mp4即可。
【效果截图】
处理之前：
功能截图：
处理之后：
【完整代码】
AddPrefixSuffix.bat
[Asm] 纯文本查看 复制代码 @echo off
REM 设置片头视频文件（请确保片头、片尾、正片都是分辨率相同的视频文件）
set "FilePrefix=Resource\PianTou.mp4"
REM 设置片尾视频文件（请确保片头、片尾、正片都是分辨率相同的视频文件）
set "FileSuffix=Resource\PianWei.mp4"
REM 合并之后的视频放在哪个文件夹
set "FolderOut=Result"
cd /d "%~dp0"
set "FileList=MergeVideo.txt"
md "%FolderOut%" 2>nul
echo [1] 添加片头
echo [2] 添加片尾
echo [3] 添加片头和片尾
choice /c 123 /m "请输入数字："
if %errorlevel% == 1 (
for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (
> "%FileList%" echo file '%FilePrefix%'
>>"%FileList%" echo file '%%i'
ffmpeg.exe -f concat -safe 0 -i "%FileList%" -c copy "%FolderOut%\%%i"
)
) else if %errorlevel% == 2 (
for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (
> "%FileList%" echo file '%%i'
>>"%FileList%" echo file '%FileSuffix%'
ffmpeg.exe -f concat -safe 0 -i "%FileList%" -c copy "%FolderOut%\%%i"
)
) else if %errorlevel% == 3 (
for /f "delims=" %%i in ('dir /b /a-d *.mp4') do (
> "%FileList%" echo file '%FilePrefix%'
>>"%FileList%" echo file '%%i'
>>"%FileList%" echo file '%FileSuffix%'
ffmpeg.exe -hide_banner -loglevel info -f concat -safe 0 -i "%FileList%" -c copy "%FolderOut%\%%i"
)
) | 
[复制链接]
发表于 2023-12-31 12:06
|
发表于 2023-12-31 17:24
