关于Excel文档使用中存在的一个问题

采蘑菇的丶小L

家人在使用文档中不知道怎么操作的，导致多个文件夹中的Excel表格出现问题，具体问题是：每一个表格下面都插入了同一个工作表，原本的表格内容都移到了第二个工作表中，已经出现几次了，每次都是挨个删除表格底下的第一个工作表，请问这是什么操作造成的？能不能批量删除多个表格中的第一个工作表？

ToDesk01

表不多手动删除下，这种删除量有很大吗？批量删除多个都是Sheet1看看你wps支持vba没，打开VBA编辑器：按 Alt + F11 打开VBA编辑器。

插入模块：右键点击“VBAProject”，选择“插入” -> “模块”。

粘贴以下代码

Sub 删除的工作表Sheet1()
    Dim folderPath As String
    Dim fileName As String
    Dim wb As Workbook
    Dim ws As Worksheet
    Dim sheetName As String
    Dim fd As FileDialog
   
    sheetName = "Sheet1" ' 要删除的工作表名称

    ' 创建文件夹对话框
    Set fd = Application.FileDialog(msoFileDialogFolderPicker)
    If fd.Show = -1 Then
        folderPath = fd.SelectedItems(1) & "\" ' 获取用户选择的文件夹路径
    Else
        MsgBox "未选择文件夹，操作已取消。"
        Exit Sub
    End If

    ' 获取文件夹中的第一个Excel文件
    fileName = Dir(folderPath & "*.xls*") ' 适用于所有Excel文件（.xls和.xlsx）

    ' 遍历所有Excel文件
    Do While fileName <> ""
        ' 打开工作簿
        Set wb = Workbooks.Open(folderPath & fileName)
        
        ' 遍历工作簿中的所有工作表
        For Each ws In wb.Worksheets
            If ws.Name = sheetName Then
                Application.DisplayAlerts = False ' 关闭删除确认提示
                ws.Delete
                Application.DisplayAlerts = True ' 重新打开删除确认提示
            End If
        Next ws
        
        ' 保存并关闭工作簿
        wb.Close SaveChanges:=True
        
        ' 获取下一个Excel文件
        fileName = Dir
    Loop
   
    MsgBox "操作完成！"
End Sub

要删除的说有表放到一个文件夹下，选择这个文件夹
F8运行 完事都删了，注意删除前自己检查数据确认后在删。

freelive

删除Excel表格中自创的模板
https://jingyan.baidu.com/article/25648fc171449c9191fd00f8.html

猪包子

你这是不小心创建了副本，要么是右键创建了副本，要么按到了快捷键。比如CTRL失灵或者不小心按着，鼠标拉动标签（就是写着sheet1，sheet2那里），就会直接复制多一个副本。如果不是不小心按到，那就检查ctrl键是不是坏了。