【bat 原创】一些你可能会用到的批处理成品

hacker1983

纯萌新，刚入坑。发布内容如违规请管理员帮我下架就行。（别删我号）
所有代码全部开源，都是结合最近工作，随手写的。估计运维的兄弟可能能用到吧，不处理任何售后问题，没时间，没精力。主要是懒。做这些代码也主要是懒；

1.更改计算机名，IP地址；
@echo off
rem 更改计算机名
set /p newname=请输入新计算机名：

wmic computersystem where name="%computername%" call rename name="%newname%"

REM 更改网络设置
set /p ipaddress="请输入新的IP地址: "
set /p subnetmask="请输入新的子网掩码: "
set /p gateway="请输入新的网关: "
set /p dns1="请输入首选DNS服务器: "


netsh interface ipv4 set address name="本地连接" static %ipaddress% %subnetmask% %gateway%
netsh interface ipv4 add dnsserver name="本地连接" address=%dns1% index=1
netsh interface ipv4 add dnsserver name="本地连接" address=%dns2% index=2

echo 完成.
pause

2.一键添加host和IE添加受信任站点；
我分两段写了，都要用的人就合并就行。地址我瞎写的，需要自己改就行。

@echo off
echo 192.168.0.1   www.baidu.com >> C:\Windows\System32\drivers\etc\hosts
echo 192.168.0.2   www.google.hk >> C:\Windows\System32\drivers\etc\hosts
exit

添加受信任站点是适用于win7和win10的，win7下会报个错误，不影响，是因为要刷新IE的过

@echo off
setlocal

:: 添加https://niu.baidu.com到IE受信任站点
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\baidu.com\niu" /v https /t REG_DWORD /d 00000002 /f

:: 添加https://niu.google.hk到IE受信任站点
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Domains\google.hk\niu" /v https /t REG_DWORD /d 00000002 /f

:: 刷新IE设置
%systemroot%\System32\cmd.exe /c "%systemroot%\System32\ie4uinit.exe" -ClearIconCache
%systemroot%\System32\rundll32.exe %systemroot%\System32\iesetup.dll, IEAccessSysInst
%systemroot%\System32\cmd.exe /c "%systemroot%\System32\ie4uinit.exe" -UserIconConfig

echo 受信任站点已添加完成！
pause

3.一键安装证书（自己改路径和名称不用再说了吧！！！）

@echo off
certutil -addstore root C:\soft\11111z-ca-root-new.cer
certutil -addstore root C:\soft\MicrosoftRootCertificateAuthority2011.cer
certutil -addstore root C:\soft\22222-CA01.cer

4.win7自带游戏删除
@echo off
echo 正在卸载 Windows 7 自带游戏，请稍等...
ping -n 4 127.0.0.1 > nul
for %%a in (bspatch.exe cards.dll freecell.exe mshearts.exe sol.exe spider.exe winmine.exe) do (
    takeown /f "%ProgramFiles%\Microsoft Games\%%a" > nul
    icacls "%ProgramFiles%\Microsoft Games\%%a" /grant administrators:F > nul
    del /f /q "%ProgramFiles%\Microsoft Games\%%a" > nul
)
rd /s /q "%ProgramFiles%\Microsoft Games" > nul
echo 完成。Windows 7 自带游戏已被卸载。
pause

有爱自取就好，886.

hacker1983

TabKey9 发表于 2023-6-8 17:48
整的我都有点懵了，这也是批处理啊！shell只是我选的代码高亮，虽然我不知道shell和bat什么关系，但这段 ...

我的意思是我的win7不能运行你的代码，要改成：

@echo off
net session >nul 2>&1
if %errorLevel% == 0 (
    goto UACAdmin
) else (
    goto UACPrompt
)

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params=%*
    echo UAC.ShellExecute "%~s0", "%params%", "", "runas", 1 >> "%temp%\getadmin.vbs"
    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:UACAdmin
    pushd "%~dp0"
    color 0a
    echo 当前运行路径是：%cd%
    echo 已获取管理员权限


pause

ε=(´ο｀*)))唉，单位机子烂呀！！！

TabKey9

给楼主借鉴，可能以后用得上：

[Shell] 纯文本查看 复制代码

@echo off
if exist "%SystemRoot%\SysWOW64" path %path%;%windir%\SysNative;%SystemRoot%\SysWOW64;%~dp0
bcdedit >nul
if '%errorlevel%' NEQ '0' (goto UACPrompt) else (goto UACAdmin)
:UACPrompt
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","::",,"runas",1)(window.close)&exit
exit /B
:UACAdmin
cd /d "%~dp0"
color 0a
@echo 当前运行路径是：%CD%
@echo 已获取管理员权限

shipon

1.更改计算机名，IP地址；       win10不行

OrData

收藏，感谢！觉得有用，虽然可能不用，但打开了思路啊。

梦中之梦

先鼓励一下，用处不大就是

bbs119

win7自带游戏那么好玩，你居然还卸载 ，win10我还特意去找来安装上的

hacker1983

TabKey9 发表于 2023-6-8 14:07
给楼主借鉴，可能以后用得上：
[mw_shl_code=shell,true]@echo off
if exist "%SystemRoot%\SysWOW64" pa ...

感谢兄弟，我考虑的是向下兼容的问题，shell运行不到win7  很多带还原的机子都是win7系统，或者说我们单位机子烂。。。。。

hacker1983

shipon 发表于 2023-6-8 11:54
1.更改计算机名，IP地址；       win10不行

底层原理都是一样的，你看看你的本地连接是本地连接1  2  3  还是本地连接
改改应该能用，或者直接chatGPT不就ok了吗？

TabKey9

hacker1983 发表于 2023-6-8 17:10
感谢兄弟，我考虑的是向下兼容的问题，shell运行不到win7  很多带还原的机子都是win7系统，或者说我们单 ...

整的我都有点懵了，这也是批处理啊！shell只是我选的代码高亮，虽然我不知道shell和bat什么关系，但这段代码确实是.bat跟.cmd可以运行的啊，你可以试试~