1、申 请 I D：chen628
2、个人邮箱：3438871@qq.com
3、原创技术文章：
这个小工具是读取网页上的一些自己需要的内容，然后写入到MySQL数据库，
有账号登录，还有读取中关村上一些信息，我自己整理的，有些代码是自己写，部分代码用模块，极少一部分，需要上传原文件的，留言
希望能通过审核，
以下代码只是 部分，我用了部分模块，还有一些敏感的我不贴出来了，
.版本 2
.支持库 mysql
.支持库 iext
.支持库 spec
.支持库 EThread
.程序集 窗口程序集_启动窗口
.程序集变量 集_登录判断, 文本型
.程序集变量 集_网页源代码, 文本型
.程序集变量 集_总页数, 文本型
.程序集变量 集_开始数, 文本型
.程序集变量 集_商品总数, 文本型
.程序集变量 集_计数时长, 整数型
.程序集变量 集_Excel程序, EXCEL程序对象
.程序集变量 集_单元格, 单元格对象
.程序集变量 集_索引行列, 文本型, , "0"
.程序集变量 集_句柄, 整数型
.子程序 __启动窗口_创建完毕
.局部变量 局_寻到文本, 文本型
.局部变量 局_文件名, 文本型
窗口位置对齐 ()
.如果 (_链接MySQL () ＝ 假)
信息框 (“数据库链接失败！！”, 0, “错误提示”, _启动窗口)
编辑框_获取网页代码.加入文本 (“：MySQL链接失败！！”)
.否则
.如果真 (执行SQL语句 (全_M句柄, “set names 'gbk'”) ＝ 真)
编辑框_获取网页代码.加入文本 (“：MySQL链接成功！！”)
.如果真结束
.如果结束
选择夹_主页.现行子夹 ＝ 0
_结束进程 (“EXCEL.EXE”)
.如果真 (选择夹_主页.现行子夹 ＝ 0)
局_文件名 ＝ 取运行目录 () ＋ “\账号_” ＋ 到文本 (选择夹_主页.现行子夹) ＋ “.txt”
.如果真 (选择夹_主页.现行子夹 ＝ 0)
局_寻到文本 ＝ 寻找文件 (局_文件名, 1 ＋ 2)
.如果 (局_寻到文本 ≠ “”)
全_账号 ＝ 编码_URL解码 (文本_取左边 (到文本 (读入文件 (局_寻到文本)), “，”, , ))
全_密码 ＝ 编码_URL解码 (文本_取右边 (到文本 (读入文件 (局_寻到文本)), “，”, , ))
.否则
载入 (窗口_设置账号密码, _启动窗口, 真)
.如果结束
.如果真结束
.如果真结束
.子程序 _按钮_链接网页_被单击
按钮_链接网页.禁止 ＝ 真
集_登录判断 ＝ 登录_网页访问 (#登录地址, 全_账号, 全_密码)
.如果真 (寻找文本 (集_登录判断, “登录成功”, , 假) ＞ 0)
时钟1.时钟周期 ＝ 1000
集_计数时长 ＝ 5
按钮_写到Mysql.禁止 ＝ 假
.如果真结束
.子程序 _按钮_获取主导航_被单击
.局部变量 局_网页源代码, 文本型
.局部变量 局_链接代码, 文本型, , "0"
.局部变量 局_取A链接, 文本型, , "0"
.局部变量 局_a, 整数型
.局部变量 局_取导航地址, 文本型
.局部变量 局_导航全名, 文本型
.局部变量 局_b, 整数型
.局部变量 局_母菜单名称, 文本型
.局部变量 局_子菜单名, 文本型
.局部变量 局_子URL, 文本型
.局部变量 局_树母, 整数型
.局部变量 局_树子, 整数型
.局部变量 局_菜单取文本, 文本型
.局部变量 局_树子_地址, 整数型
.局部变量 局_子菜单取文本, 文本型
.局部变量 局_子菜单取分类名数组, 文本型, , "0"
.局部变量 局_c, 整数型
.局部变量 局_子分类名, 文本型
.局部变量 局_子分类URL, 文本型
.局部变量 局_树子_U, 整数型
编辑框_获取网页代码.内容 ＝ “”
树型框_获取网站导航.清空 ()
.如果 (寻找文本 (集_登录判断, “登录成功”, , 假) ＞ 0)
局_网页源代码 ＝ 网页取全源码 (#韦辰地址首页, , 全_Cookie)
局_取导航地址 ＝ 文本_取出中间文本 (局_网页源代码, “<ul class=” ＋ #引号 ＋ “category-list” ＋ #引号 ＋ “>”, “<!-- <li class=” ＋ #引号 ＋ “category-item”, , )
局_取A链接 ＝ 分割文本 (局_取导航地址, “<li class=” ＋ #引号 ＋ “category-item”, )
.计次循环首 (取数组成员数 (局_取A链接), 局_a)
局_导航全名 ＝ 文本_取出中间文本 (局_取A链接 [局_a], “<div class=” ＋ #引号 ＋ “cat-name” ＋ #引号 ＋ “><a href=” ＋ #引号, “<div class=” ＋ #引号 ＋ “cat-sub” ＋ #引号 ＋ “>”, , )
局_母菜单名称 ＝ 文本_取出中间文本 (局_导航全名, “>”, “</a></div>”, , )
.如果真 (局_母菜单名称 ≠ “”)
局_树母 ＝ 树型框_获取网站导航.加入项目 (-1, 局_母菜单名称, , , , , )
文本_取中间_批量 (局_取A链接 [局_a], “<dl class=” ＋ #引号 ＋ “sub-category” ＋ #引号 ＋ “>”, “</dl>”, 局_链接代码, , , , , , , )
.计次循环首 (取数组成员数 (局_链接代码), 局_b)
局_菜单取文本 ＝ 文本_取出中间文本 (局_链接代码 [局_b], “<dt>”, “</dt>”, , )
局_子菜单名 ＝ 文本_取出中间文本 (局_菜单取文本, #引号 ＋ “>”, “</a>”, , )
局_子URL ＝ 文本_取出中间文本 (局_链接代码 [局_b], “<dt><a href=” ＋ #引号, #引号 ＋ “ class=”, , )
局_树子 ＝ 树型框_获取网站导航.加入项目 (局_树母, 局_子菜单名, , , , , )
局_树子_地址 ＝ 树型框_获取网站导航.加入项目 (局_树子, 局_子URL, , , , , )
局_子菜单取文本 ＝ 文本_取出中间文本 (局_链接代码 [局_b], “<dd class=” ＋ #引号 ＋ “clearfix” ＋ #引号 ＋ “>”, “</dd>”, , )
文本_取中间_批量 (局_子菜单取文本, “<a href=” ＋ #引号, “</a>”, 局_子菜单取分类名数组, , , , , , , )
.计次循环首 (取数组成员数 (局_子菜单取分类名数组), 局_c)
局_子分类名 ＝ 文本_取右边 (局_子菜单取分类名数组 [局_c], “>”, , )
局_子分类URL ＝ 文本_取左边 (局_子菜单取分类名数组 [局_c], #引号 ＋ “ class=”, , )
局_树子_U ＝ 树型框_获取网站导航.加入项目 (局_树子_地址, 局_子分类名, , , , , )
树型框_获取网站导航.加入项目 (局_树子_U, 局_子分类URL, , , , , )
.计次循环尾 ()
.计次循环尾 ()
.如果真结束
.计次循环尾 ()
树型框_获取网站导航.扩展 (局_b)
编辑框_获取网页代码.加入文本 (局_网页源代码)
.否则
信息框 (“cookie验证失败！！”, 0, “错误提示”, )
.如果结束
.子程序 _树型框_获取网站导航_项目被选择
.参数 选择方式, 整数型
.局部变量 局_选中的文本, 文本型
.局部变量 局_取出需要文本, 文本型
.如果真 (选择方式 ＝ 1)
局_选中的文本 ＝ 树型框_获取网站导航.取项目文本 (树型框_获取网站导航.现行选中项)
.如果真 (寻找文本 (局_选中的文本, “html”, , 假) ＞ 0)
超级列表框_获取产品.全部删除 ()
编辑框_获取网页代码.内容 ＝ “”
标签_获取信息.标题 ＝ #韦辰地址首页 ＋ 局_选中的文本
集_网页源代码 ＝ 网页_访问S (标签_获取信息.标题, 0, , 全_Cookie, , , , , , , , , , , , , )
编辑框_获取网页代码.加入文本 (集_网页源代码)
局_取出需要文本 ＝ 文本_取出中间文本 (集_网页源代码, “<span class=” ＋ #引号 ＋ “page-count” ＋ #引号 ＋ “>”, “<span class=” ＋ #引号 ＋ “page-action” ＋ #引号 ＋ “>”, , )
集_开始数 ＝ 文本_取出中间文本 (局_取出需要文本, “page-current” ＋ #引号 ＋ “>”, “</span>/<span class=”, , )
集_总页数 ＝ 文本_取出中间文本 (局_取出需要文本, “page-total” ＋ #引号 ＋ “>”, “</span></span>”, , )
集_商品总数 ＝ 文本_取出中间文本 (集_网页源代码, “op-search-result” ＋ #引号 ＋ “>”, “</b>件商品)”, , )
标签_页数.标题 ＝ “当前 ” ＋ 集_开始数 ＋ “ 页/ ” ＋ “共 ” ＋ 集_总页数 ＋ “ 页” ＋ “ ● 总商品数 ” ＋ 集_商品总数 ＋ “ 件商品”
.如果 (到数值 (集_总页数) ≤ 1)
按钮_下页.禁止 ＝ 真
.否则
按钮_下页.禁止 ＝ 假
.如果结束
按钮_上页.禁止 ＝ 真
_按钮_读取信息_被单击 ()
.如果真结束
.如果真结束
.子程序 _按钮_上页_被单击
.局部变量 局_商品页, 文本型
.局部变量 局_翻页递交信息, 文本型
.局部变量 局_开始页减, 整数型
.局部变量 局_页面编码转换, 字节集
按钮_下页.禁止 ＝ 假
.如果真 (到整数 (集_开始数) ≤ 1)
信息框 (“已经是第一页了，上面没有了”, 0, “错误提示”, )
按钮_上页.禁止 ＝ 真
返回 ()
.如果真结束
集_网页源代码 ＝ “”
编辑框_获取网页代码.内容 ＝ “”
局_开始页减 ＝ 到数值 (集_开始数) － 1
局_商品页 ＝ 文本_取出中间文本 (标签_获取信息.标题, “gallery-”, “.html”, , )
集_开始数 ＝ 到文本 (局_开始页减)
标签_页数.标题 ＝ “当前 ” ＋ 集_开始数 ＋ “ 页/ ” ＋ “共 ” ＋ 集_总页数 ＋ “ 页” ＋ “ ● 总商品数 ” ＋ 集_商品总数 ＋ “ 件商品”
集_网页源代码 ＝ 翻页_网页访问 (#翻页地址, 局_商品页, 集_开始数, 全_Cookie)
编辑框_获取网页代码.加入文本 (集_网页源代码)
_按钮_读取信息_被单击 ()
.如果真 (到整数 (集_开始数) ≤ 1)
按钮_上页.禁止 ＝ 真
.如果真结束
.子程序 _按钮_下页_被单击
.局部变量 局_商品页, 文本型
.局部变量 局_开始页减, 整数型
.局部变量 局_页面编码转换, 字节集
.局部变量 局_a, 整数型
按钮_上页.禁止 ＝ 假
编辑框_获取网页代码.内容 ＝ “”
.如果真 (到整数 (集_开始数) ≥ 到整数 (集_总页数))
信息框 (“已经是最后页了，下面没有了”, 0, “错误提示”, )
按钮_下页.禁止 ＝ 真
返回 ()
.如果真结束
集_网页源代码 ＝ “”
局_开始页减 ＝ 到数值 (集_开始数) ＋ 1
局_商品页 ＝ 文本_取出中间文本 (标签_获取信息.标题, “gallery-”, “.html”, , )
集_开始数 ＝ 到文本 (局_开始页减)
集_开始数 ＝ 到文本 (局_开始页减)
标签_页数.标题 ＝ “当前 ” ＋ 集_开始数 ＋ “ 页/ ” ＋ “共 ” ＋ 集_总页数 ＋ “ 页” ＋ “ ● 总商品数 ” ＋ 集_商品总数 ＋ “ 件商品”
集_网页源代码 ＝ 翻页_网页访问 (#翻页地址, 局_商品页, 集_开始数, 全_Cookie)
编辑框_获取网页代码.加入文本 (集_网页源代码)
_按钮_读取信息_被单击 ()
.如果真 (到整数 (集_开始数) ≥ 到整数 (集_总页数))
按钮_下页.禁止 ＝ 真
.如果真结束
.子程序 _按钮_读取信息_被单击
.局部变量 局_批量源代码, 文本型, , "0"
.局部变量 局_商品名, 文本型
.局部变量 局_图片, 文本型
.局部变量 局_单价, 文本型
.局部变量 局_a, 整数型
.局部变量 局_行, 整数型
.局部变量 局_产品地址, 文本型
.局部变量 局_取子商品代码, 文本型
.局部变量 局_子商品名数组, 文本型, , "0"
.局部变量 局_子a, 整数型
.局部变量 局_子商品名, 文本型
编辑框_获取网页代码.内容 ＝ “”
超级列表框_获取产品.全部删除 ()
文本_取中间_批量 (集_网页源代码, “<li class=” ＋ #引号 ＋ “goods-item”, “<a class=” ＋ #引号 ＋ “btn btn-major”, 局_批量源代码, , , , , , , )
.计次循环首 (取数组成员数 (局_批量源代码), 局_a)
局_图片 ＝ 文本_取左边 (文本_取出中间文本 (局_批量源代码 [局_a], “data-src=” ＋ #引号, #引号 ＋ “ alt=”, , ), “?”, , )
局_商品名 ＝ 文本_取右边 (文本_取出中间文本 (局_批量源代码 [局_a], “<a href=”, “</a></h3>”, ), “>”, , )
局_单价 ＝ 文本_取出中间文本 (局_批量源代码 [局_a], “>￥”, “</ins>”, , )
局_产品地址 ＝ 文本_取左边 (文本_取出中间文本 (局_批量源代码 [局_a], “<a href=” ＋ #引号, “</a></h3>”, ), #引号 ＋ “>”, , )
局_取子商品代码 ＝ 文本_取出中间文本 (局_批量源代码 [局_a], “<ul class=” ＋ #引号 ＋ “j_selectList” ＋ #引号 ＋ “>”, “</ul>”, , )
.如果 (寻找文本 (局_取子商品代码, “默认”, , 假) ＜ 0)
文本_取中间_批量 (局_取子商品代码, “li class=” ＋ #引号 ＋ “sku-li” ＋ #引号, “</li>”, 局_子商品名数组, , , , , , , )
.计次循环首 (取数组成员数 (局_子商品名数组), 局_子a)
局_子商品名 ＝ 文本_取右边 (局_子商品名数组 [局_子a], “>”, , )
局_单价 ＝ 文本_取出中间文本 (局_子商品名数组 [局_子a], “price=” ＋ #引号, #引号 ＋ “>”, , )
局_行 ＝ 超级列表框_获取产品.插入表项 (, , , , , )
超级列表框_获取产品.置标题 (局_行, 0, 到文本 (局_行 ＋ 1))
超级列表框_获取产品.置标题 (局_行, 1, 局_商品名 ＋ “ ” ＋ 局_子商品名)
超级列表框_获取产品.置标题 (局_行, 2, 局_单价)
超级列表框_获取产品.置标题 (局_行, 3, 局_产品地址)
超级列表框_获取产品.置标题 (局_行, 4, 局_图片)
.计次循环尾 ()
.否则
局_行 ＝ 超级列表框_获取产品.插入表项 (, , , , , )
超级列表框_获取产品.置标题 (局_行, 0, 到文本 (局_行 ＋ 1))
超级列表框_获取产品.置标题 (局_行, 1, 局_商品名)
超级列表框_获取产品.置标题 (局_行, 2, 局_单价)
超级列表框_获取产品.置标题 (局_行, 3, 局_产品地址)
超级列表框_获取产品.置标题 (局_行, 4, 局_图片)
.如果结束
.计次循环尾 ()
编辑框_获取网页代码.加入文本 (集_网页源代码)
.子程序 _韦辰网站数据_被选择
选择夹_主页.现行子夹 ＝ 0
_启动窗口.标题 ＝ _启动窗口.标题 ＋ “获取网站商品价格信息-→韦辰网站数据”
清除数据 ()
.子程序 _中关村网站数据_被选择
选择夹_主页.现行子夹 ＝ 1
_启动窗口.标题 ＝ “获取网站商品价格信息-→中关村网站数据”
清除数据 ()
.子程序 _倪德网站数据_被选择
选择夹_主页.现行子夹 ＝ 2
_启动窗口.标题 ＝ “获取网站商品价格信息-→倪德网站数据”
清除数据 ()
.子程序 _选择夹_主页_鼠标右键被按下, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
弹出菜单 (选择网站, , )
.子程序 _设置账号和密码_被选择
载入 (窗口_设置账号密码, _启动窗口, 真)
.子程序 _时钟1_周期事件
.如果 (集_计数时长 ＞ 0)
集_计数时长 ＝ 集_计数时长 － 1
标签_页数.标题 ＝ “等待链接 ” ＋ 到文本 (集_计数时长) ＋ “ 秒........”
.否则
时钟1.时钟周期 ＝ 0
标签_页数.标题 ＝ “等待获取主导航”
按钮_获取主导航.禁止 ＝ 假
延迟 (3000)
按钮_链接网页.禁止 ＝ 假
.如果结束
.子程序 清除数据
树型框_获取网站导航.清空 ()
超级列表框_获取产品.全部删除 ()
标签_获取信息.标题 ＝ “请先链接网站”
标签_页数.标题 ＝ “页数”
按钮_获取主导航.禁止 ＝ 真
连续赋值 (“”, 编辑框_获取网页代码.内容, 集_总页数, 集_开始数, 集_登录判断, 集_商品总数, 集_网页源代码)
.子程序 _导入Excel文件_被选择
选择夹_主页.现行子夹 ＝ 2
清除数据 ()
.子程序 _按钮_打开excel文件_被单击
.局部变量 局_标题, 文本型, , "0"
.局部变量 局_t, 整数型
.局部变量 局_列号, 整数型
.局部变量 局_行号, 整数型
.局部变量 局_文本, 文本型
.局部变量 局_b, 整数型
.局部变量 局_行索引, 整数型
.局部变量 局_分割行列, 文本型, , "0"
.局部变量 局_取行数, 整数型
.局部变量 局_取列数, 整数型
.局部变量 局_取表格数, 整数型
.局部变量 局_文本数组, 文本型, , "0"
.局部变量 局_a, 整数型
.局部变量 局_excel_地址, 文本型
超级列表框_Excel数据.全部删除 ()
局_标题 ＝ 分割文本 (编辑框_导入标题.内容, “|”, )
.计次循环首 (取数组成员数 (局_标题), 局_t)
超级列表框_Excel数据.插入列 (局_t － 1, 局_标题 [局_t], 超级列表框_Excel数据.宽度 ÷ 取数组成员数 (局_标题) － 5, 0, , )
.计次循环尾 ()
.如果真 (集_Excel程序.创建 () ＝ 假)
信息框 (“Excel 创建失败！！”, 0, “错误提示”, )
返回 ()
.如果真结束
局_excel_地址 ＝ _取通用文件名 (通用对话框_Excel地址)
标签_Excel文件.标题 ＝ 局_excel_地址
.如果真 (集_Excel程序.打开文件 (局_excel_地址, , , ) ＝ 真)
局_取表格数 ＝ 集_Excel程序.取工作表数 ()
.计次循环首 (局_取表格数, 局_a)
局_取行数 ＝ 集_Excel程序.取行数 (局_a)
局_取列数 ＝ 集_Excel程序.取列数 (局_a)
.如果真 (局_取行数 ＞ 1 且 局_取列数 ＞ 1)
加入成员 (集_索引行列, 到文本 (局_a) ＋ “,” ＋ 到文本 (局_取行数) ＋ “,” ＋ 到文本 (局_取列数))
.如果真结束
.计次循环尾 ()
集_单元格.置程序 (集_Excel程序)
.计次循环首 (取数组成员数 (集_索引行列), 局_b)
局_分割行列 ＝ 分割文本 (集_索引行列 [局_b], “,”, )
' 数组 1=索引，数组 2=行数，数组 3=列数
.计次循环首 (到整数 (局_分割行列 [2]), 局_行号)
.如果真 (局_行号 ＞ 2)
局_行索引 ＝ 超级列表框_Excel数据.插入表项 (-1, , , , , )
.计次循环首 (到整数 (局_分割行列 [3]), 局_列号)
局_文本 ＝ 集_单元格.取纯文本 (到整数 (局_分割行列 [1]), 局_行号, 局_列号, )
超级列表框_Excel数据.置标题 (局_行索引, 局_列号 － 1, 局_文本)
.计次循环尾 ()
.如果真结束
.计次循环尾 ()
.计次循环尾 ()
.如果真结束
集_Excel程序.退出程序 ()
.子程序 __启动窗口_将被销毁
' 关闭MySql (全_M句柄)
关闭线程句柄 (集_句柄)
断开MySql (全_M句柄)
_结束进程 (“EXCEL.EXE”)
.子程序 _Mysql设置_被选择
载入 (窗口_Mysql设置, _启动窗口, 真)
.子程序 _按钮_写到Mysql_被单击
.子程序 _树型框_获取网站导航_鼠标右键被按下, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
.如果 (树型框_获取网站导航.现行选中项 ≥ 0)
增加商品.禁止 ＝ 真
增加分类.禁止 ＝ 假
.否则
增加商品.禁止 ＝ 假
增加分类.禁止 ＝ 真
.如果结束
弹出菜单 (增加, , )
.子程序 _增加分类_被选择
.局部变量 局_项目数, 整数型
.局部变量 局_a, 整数型
.局部变量 局_父目录, 整数型
.局部变量 局_文本, 文本型
.局部变量 局_父文本, 文本型
.局部变量 局_父文本组, 文本型, , "0"
.局部变量 局_b, 整数型
.局部变量 局_c, 整数型
.局部变量 局_序号, 整数型
.局部变量 局_SQL语句, 文本型
.局部变量 局_子文本, 文本型
.局部变量 局_记录集, 整数型
.局部变量 局_yid, 文本型
.局部变量 局_排序, 整数型
局_项目数 ＝ 树型框_获取网站导航.取项目数 ()
.如果真 (局_项目数 ≤ 0)
信息框 (“没有分类不能增加！”, 0, “错误提示”, _启动窗口)
返回 ()
.如果真结束
编辑框_获取网页代码.内容 ＝ “”
.如果真 (树型框_获取网站导航.取项目数 () ＝ 0)
返回 ()
.如果真结束
.如果真 (全_M句柄 ＝ 0)
信息框 (“数据库链接失败！！”, 0, “链接错误”, _启动窗口)
返回 ()
.如果真结束
.计次循环首 (局_项目数, 局_a)
.如果真 (树型框_获取网站导航.取父项目 (局_a － 1) ＝ -1)
局_文本 ＝ 树型框_获取网站导航.取项目文本 (局_a － 1)
' 调试输出 (局_文本)
.' 如果 (_判断是否有数据 (局_文本, “yfenl_b”, “yfl_id”, “yfl_n”) ＝ 假)
' 局_序号 ＝ 局_序号 ＋ 1
' 局_SQL语句 ＝ “insert into yfenl_b(yfl_n,yfl_px)values('” ＋ 局_文本 ＋ “','” ＋ 到文本 (局_序号) ＋ “')”
.' 如果真 (执行SQL语句 (全_M句柄, 局_SQL语句) ＝ 真)
' 编辑框_获取网页代码.加入文本 (“加入一级分类：” ＋ 局_文本 ＋ “ 成功！！” ＋ #换行符)
.如果真结束
.否则
' 编辑框_获取网页代码.加入文本 (“**一级分类：” ＋ 局_文本 ＋ “ 已经存在不用添加！” ＋ #换行符)
.如果结束
加入成员 (局_父文本组, 局_文本)
.如果真结束
.计次循环尾 ()
.计次循环首 (局_项目数, 局_b)
局_父文本 ＝ 树型框_获取网站导航.取项目文本 (树型框_获取网站导航.取父项目 (局_b － 1))
.计次循环首 (取数组成员数 (局_父文本组), 局_c)
局_子文本 ＝ 树型框_获取网站导航.取项目文本 (局_b － 1)
.如果真 (局_父文本 ＝ 局_父文本组 [局_c])
局_排序 ＝ 局_排序 ＋ 1
' spflid spfl_mc spfl_px
.' 如果真 (执行SQL语句 (全_M句柄, “select spflid from spfl_b where spfl_mc='” ＋ 局_父文本 ＋ “'”) ＝ 真)
' ' 局_记录集 ＝ 取记录集 (全_M句柄)
' ' 读字段值 (局_记录集, “yfl_id”, 局_yid)
.如果 (_判断是否有数据 (局_子文本, “spfl_b”, “spflid”, “spfl_mc”) ＝ 假)
' 调试输出 (到文本 (局_排序) ＋ “：” ＋ 局_子文本)
局_SQL语句 ＝ “insert into spfl_b(spfl_mc,spfl_px)values('” ＋ 局_子文本 ＋ “','” ＋ 到文本 (局_排序) ＋ “')”
调试输出 (局_SQL语句)
.如果真 (执行SQL语句 (全_M句柄, 局_SQL语句) ＝ 真)
编辑框_获取网页代码.加入文本 (“所属分类：” ＋ 局_父文本 ＋ “ ，写入分类文本：” ＋ 局_子文本 ＋ “ 成功！！” ＋ #换行符)
.如果真结束
.否则
编辑框_获取网页代码.加入文本 (“**所属分类：” ＋ 局_父文本 ＋ “ ，分类：” ＋ 局_子文本 ＋ “ 已经存在不用重复添加！” ＋ #换行符)
.如果结束
.如果真结束
.如果真结束
.计次循环尾 ()
.计次循环尾 ()
释放记录集 (局_记录集)
.子程序 _超级列表框_获取产品_鼠标右键被按下, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
.如果 (超级列表框_获取产品.现行选中项 ≥ 0)
增加分类.禁止 ＝ 真
增加商品.禁止 ＝ 假
.否则
增加分类.禁止 ＝ 假
增加商品.禁止 ＝ 真
.如果结束
弹出菜单 (增加, , )
.子程序 _增加商品_被选择
.局部变量 局_分类, 文本型
.局部变量 局_语句, 文本型
.局部变量 局_记录集, 整数型
.局部变量 局_id, 文本型
.局部变量 局_表数, 整数型
.局部变量 局_a, 整数型
.局部变量 局_名称, 文本型
.局部变量 局_单价, 文本型
.局部变量 局_图片, 文本型
编辑框_获取网页代码.内容 ＝ “”
局_分类 ＝ 树型框_获取网站导航.取项目文本 (树型框_获取网站导航.取父项目 (树型框_获取网站导航.现行选中项))
.如果真 (寻找文本 (局_分类, “.html”, , 假) ＞ 0)
信息框 (“选中分类错误！”, 0, “错误提示”, _启动窗口)
返回 ()
.如果真结束
局_语句 ＝ “select spflid from spfl_b where spfl_mc='” ＋ 局_分类 ＋ “'”
.如果真 (执行SQL语句 (全_M句柄, 局_语句) ＝ 真)
局_记录集 ＝ 取记录集 (全_M句柄)
读字段值 (局_记录集, “spflid”, 局_id)
.如果真 (局_id ＝ “”)
信息框 (“取分类名称错误！请重新选中分类！”, 0, “错误提示”, _启动窗口)
返回 ()
.如果真结束
.如果真结束
局_表数 ＝ 超级列表框_获取产品.取表项数 ()
.如果真 (局_表数 ≤ 0)
信息框 (“没有数据！无法增加！”, 0, “错误提示”, _启动窗口)
返回 ()
.如果真结束
.计次循环首 (局_表数, 局_a)
局_名称 ＝ 超级列表框_获取产品.取标题 (局_a － 1, 1)
局_单价 ＝ 超级列表框_获取产品.取标题 (局_a － 1, 2)
局_图片 ＝ 超级列表框_获取产品.取标题 (局_a － 1, 4)
.如果真 (寻找文本 (局_名称, “*”, , 假) ＞ 0)
局_名称 ＝ 子文本替换 (局_名称, “*”, “”, , , 真)
.如果真结束
.如果 (_判断是否有数据 (局_名称, “spgl”, “spid”, “spmc”) ＝ 假)
局_语句 ＝ “insert into spgl(spmc,spssfl,spjhj,sppic)values('” ＋ 局_名称 ＋ “','” ＋ 局_id ＋ “','” ＋ 局_单价 ＋ “','” ＋ 局_图片 ＋ “')”
.如果真 (执行SQL语句 (全_M句柄, 局_语句) ＝ 真)
编辑框_获取网页代码.加入文本 (“增加商品名：” ＋ 局_名称 ＋ “ 成功！” ＋ #换行符)
.如果真结束
.否则
编辑框_获取网页代码.加入文本 (“**增加商品名：” ＋ 局_名称 ＋ “ 已经存在！不用重复添加！” ＋ #换行符)
.如果结束
.计次循环尾 ()
释放记录集 (局_记录集)
|
吾爱游客
发表于 2023-1-1 09:40
