Windows11驱动备份和还原

83835332

[Asm] 纯文本查看 复制代码

@echo off
setlocal
:: 锁定当前目录到脚本所在文件夹
cd /d "%~dp0"

:: 检查是否已有管理员权限
net session >nul 2>&1
if %errorLevel% == 0 goto :RUN_TOOL

:: 如果没有权限，使用 PowerShell 进行提权，并保持目录一致
powershell -Command "Start-Process '%~f0' -Verb RunAs"
exit

:RUN_TOOL
set "DEST=%~dp0DriversBackup"

:MENU
cls
echo ==================================
echo      DRIVERS BACKUP TOOL
echo ==================================
echo Location: %~dp0
echo 1. Backup
echo 2. Restore
echo 3. Exit
echo ==================================
set /p OPT=Select (1-3): 

if "%OPT%"=="1" goto DO_BACKUP
if "%OPT%"=="2" goto DO_RESTORE
if "%OPT%"=="3" exit
goto MENU

:DO_BACKUP
if not exist "%DEST%" mkdir "%DEST%"
echo Backing up...
pnputil /export-driver * "%DEST%"
echo Done. Press any key.
pause >nul
goto MENU

:DO_RESTORE
if not exist "%DEST%" (echo Folder not found. & pause & goto MENU)
echo Restoring...
pnputil /add-driver "%DEST%\*.inf" /subdirs /install
echo Done. Press any key.
pause >nul
goto MENU

这是一键备份驱动和还原驱动脚本，装完系统快速还原驱动，echo 信息改成中文程序无法运行，大佬们自行研究修改成中文

成品：https://www.ilanzou.com/s/Fzqx1RIR

goblack

和dism其实是一样的。不过这个命令专用的会简单一些

主要就两条，自己在CMD一样输入

pnputil /export-driver * "%DEST%"

pnputil /add-driver "%DEST%\*.inf" /subdirs /install


直接运行pnputil，自己就有例子

示例:

  pnputil /add-driver x:\driver.inf       <- 添加驱动程序包
  pnputil /add-driver c:\oem\*.inf        <- 添加多个驱动程序包
  pnputil /add-driver device.inf /install <- 添加并安装驱动程序包
  pnputil /enum-drivers                   <- 枚举 OEM 驱动程序包
  pnputil /delete-driver oem0.inf         <- 删除驱动程序包
  pnputil /delete-driver oem1.inf /force  <- 强制删除驱动程序包
  pnputil /export-driver oem6.inf .       <- 导出驱动程序包
  pnputil /export-driver * c:\backup      <- 导出所有驱动程序包

pixcn007

大佬，这个Win10可用不？

开创者

有没有人测试一下Win10能不能使用，效果如何

83835332

pixcn007 发表于 2026-6-23 14:29
大佬，这个Win10可用不？

你可以试试，应该是通用的

pixcn007

测试完毕：Win10可以用，Win11 22h2 不能用。

知行易乐

不会用。。。
能出个成品吗

pixcn007

83835332 发表于 2026-6-23 14:38
你可以试试，应该是通用的

大佬，在Win11 22H2下，双击窗口闪烁，不出现选项，是不是权限不够？怎么才能提升权限？

pixcn007

:: 如果没有权限，使用 PowerShell 进行提权，并保持目录一致
powershell -Command "Start-Process '%~f0' -Verb RunAs"
exit

pixcn007

pixcn007 发表于 2026-6-23 14:54
:: 如果没有权限，使用 PowerShell 进行提权，并保持目录一致
powershell -Command "Start-Process '%~f0' ...

这句代码，在我的Win11 22h2下，好像不起作用？

Aa12345

刚刚好需要，这win11 ps图片拖不进去，准备瞎搞试试，到时还原