|
|
aro
发表于 2010-6-16 20:52
今天是端午节 很高兴注册吾爱破解论坛 这个大家庭
以后就可以跟大家一起交流了 好高兴哦
也希望大家在这里完的开心
电脑自己带的小游戏蜘蛛纸牌源码
送给大家玩玩
西西!~
.版本 2
.程序集 牌类
.程序集变量 大小, 整数型
.程序集变量 花色, 整数型
.程序集变量 正面, 逻辑型
.程序集变量 层次, 整数型
.程序集变量 图片容量, 图片框
.程序集变量 横坐标, 整数型
.程序集变量 纵坐标, 整数型
.程序集变量 类别, 整数型
.子程序 _初始化, , , 当基于本类的对象被创建后，此方法会被自动调用
.子程序 _销毁, , , 当基于本类的对象被销毁前，此方法会被自动调用
.子程序 初始化, , 公开
.参数 参数_牌号, 整数型
.参数 参数_正面, 逻辑型
.参数 参数_层次, 整数型
.参数 参数_样板图片框, 图片框
.参数 参数_x, 整数型
.参数 参数_y, 整数型
.参数 参数_编号, 整数型
.参数 参数_类别, 整数型
.如果真 (取反 (是否已创建 (图片容量)))
复制窗口组件 (参数_样板图片框, 图片容量)
.如果真结束
图片容量.标记 ＝ 到文本 (参数_编号)
置图片框层次 (#顶层)
大小 ＝ 参数_牌号 ％ 13
.如果真 (大小 ＝ 0)
大小 ＝ 13
.如果真结束
.如果 (大小 ＝ 13)
花色 ＝ 参数_牌号 ＼ 13
.否则
花色 ＝ 参数_牌号 ＼ 13 ＋ 1
.如果结束
置位置 (参数_x, 参数_y)
置正反面 (参数_正面)
置类别 (参数_类别)
置层次 (参数_层次)
图片容量.可视 ＝ 真
.子程序 销毁
.如果真 (是否已创建 (图片容量))
图片容量.销毁 ()
.如果真结束
.子程序 返回图片, 字节集
.参数 参数_花色
.参数 参数_大小
.如果真 (参数_花色 ＝ 0)
返回 (#dt)
.如果真结束
.如果真 ((参数_花色 － 1) × 13 ＋ 参数_大小 ＞ 0 且 (参数_花色 － 1) × 13 ＋ 参数_大小 ≤ 54)
返回 (多项选择 ((参数_花色 － 1) × 13 ＋ 参数_大小, #p1, #p2, #p3, #p4, #p5, #p6, #p7, #p8, #p9, #p10, #p11, #p12, #p13, #p14, #p15, #p16, #p17, #p18, #p19, #p20, #p21, #p22, #p23, #p24, #p25, #p26, #p27, #p28, #p29, #p30, #p31, #p32, #p33, #p34, #p35, #p36, #p37, #p38, #p39, #p40, #p41, #p42, #p43, #p44, #p45, #p46, #p47, #p48, #p49, #p50, #p51, #p52, #p53, #p54))
.如果真结束
返回 ({ })
.子程序 置位置, , 公开
.参数 参数_x
.参数 参数_y
横坐标 ＝ 参数_x
纵坐标 ＝ 参数_y
图片容量.移动 (横坐标, 纵坐标, , )
.子程序 动画移动到, , 公开
.参数 参数_原x
.参数 参数_原y
.参数 参数_到x
.参数 参数_到y
.局部变量 x, 整数型
.局部变量 tx
.局部变量 ty
.局部变量 yx
.局部变量 yy
yx ＝ 取绝对值 (参数_原x － 参数_到x) ＼ 5
yy ＝ 取绝对值 (参数_原y － 参数_到y) ＼ 5
tx ＝ 选择 (参数_原x ＞ 参数_到x, 参数_原x － yx, 参数_原x ＋ yx)
ty ＝ 选择 (参数_原y ＞ 参数_到y, 参数_原y － yy, 参数_原y ＋ yy)
.计次循环首 (5, x)
置位置 (tx, ty)
图片容量.刷新显示 ()
延时 (1)
tx ＝ 选择 (参数_原x ＞ 参数_到x, tx － yx, tx ＋ yx)
ty ＝ 选择 (参数_原y ＞ 参数_到y, ty － yy, ty ＋ yy)
.计次循环尾 ()
置位置 (参数_到x, 参数_到y)
.子程序 取位置x, 整数型, 公开
返回 (横坐标)
.子程序 取位置y, 整数型, 公开
返回 (纵坐标)
.子程序 置正反面, , 公开
.参数 参数_正面, 逻辑型
正面 ＝ 参数_正面
图片容量.边框 ＝ 选择 (正面, 0, 5)
图片容量.图片 ＝ 选择 (正面, 返回图片 (花色, 大小), 返回图片 (0, 0))
.子程序 取正反面, 逻辑型, 公开
返回 (正面)
.子程序 置层次, , 公开
.参数 参数_层次
层次 ＝ 参数_层次
.子程序 取层次, 整数型, 公开
返回 (层次)
.子程序 置类别, , 公开
.参数 参数_类别, 整数型
类别 ＝ 参数_类别
.子程序 取类别, 整数型, 公开
返回 (类别)
.子程序 取花色, 整数型, 公开
返回 (花色)
.子程序 取大小, 整数型, 公开
返回 (大小)
.子程序 取图片框, 图片框, 公开
返回 (图片容量)
.子程序 置图片框层次, , 公开
.参数 参数_层次
图片容量.调整层次 (参数_层次)
蜘蛛纸牌源码.rar
(194.35 KB, 下载次数: 70)
|
|
[复制链接]
